TOPIC:

FUNCTION ReadWarAndPeaceTxtFile()AS VOID
LOCAL t1, t2 AS FLOAT	
LOCAL cValue, cFile AS STRING
LOCAL h AS PTR 
LOCAL i, dwLines, dwHits AS DWORD
LOCAL a, b, aStrings AS ARRAY


// https://github.com/fluentpython/example-code/blob/master/attic/sequences/war-and-peace.txt 
// ------------------------------------------------
cFile := "D:\test\vfp\war-and-peace.txt" 
// ------------------------------------------------

t1 := Seconds() 
cValue := MemoRead ( cFile  )
t2 := Seconds()

?  "MemoRead() seconds:" , t2-t1 // 0.03 secs 


t1 := Seconds() 
dwLines := MLCount( cValue ) // 65007 lines 
t2 := Seconds()

? "MLCount() seconds:" , t2-t1 , "number of lines:" , dwLines //  0.03 secs 
? "Last line:" , MemoLine( cValue , , dwLines )

aStrings := ArrayNew ( 5 )

aStrings[1] := "Russia"  // 775 occurences
aStrings[2] := "Anna"    // 293 occurences
aStrings[3] := "Czar"    // 4 occurences
aStrings[4] := "windows" // 23 occurences
aStrings[5] := "Pentium" // 0 occurences 

FOR i := 1 UPTO ALen ( aStrings ) 

	t1 := Seconds()
	dwHits := Occurs( aStrings[i], cValue )
	t2 := Seconds()
	
	? 'Occurs ("' + aStrings[i] + '" , cValue) ' , "" , "Hits:" , dwHits , "" , "seconds: " , t2 -t1 
	
NEXT	

? 
IF ( h := FOpen( cFile )) !=  F_ERROR  
	
	cValue := ""
	
	t1 := Seconds()
	FRead( h, @cValue, 4000000 )   
	t2 := Seconds()	
	
	? "FRead() seconds:" ,t2 -t1  // 0.03 secs  
	? "content of last line:" , MemoLine( cValue , , dwLines ) 

// --------------------

	a := ArrayNew ( dwLines )   
	
	FRewind(h)

	t1 := Seconds() 
	FOR i:= 1 UPTO dwLines   
		a [i] := FGetS ( h ) 
	NEXT
	t2 := Seconds() 
	
	? "ArrayNew() seconds:" , t2-t1 , "Elements:" , ALen ( a )    // 0,33 secs
	? "content of last line:" , ATail ( a ) 		
	
// -----------------
    ?
    
	b := {}
	
	FRewind ( h )
	    
	t1 := Seconds()
	DO WHILE ! FEof ( h )	
		AAdd ( b, FGetS ( h ) ) 		
	ENDDO 	
	t2 := Seconds()
	
	?  "AAdd() seconds:" , t2-t1, "Elements:" , ALen ( b )  // 0,53 secs
	?  "content of last line:" , ATail(b)  
	 
	?
	
	FClose( h )
	
ENDIF 	
	
RETURN

t1 := Seconds()
VAR x := System.IO.File.ReadAllLines(cFile)
t2 := Seconds()
?  "ReadAllLines seconds:" , t2-t1, "Elements:" , x:Length  // 0,02 secs
?  "content of last line:" , x[x:Length]